The GLIMMIX procedure might terminate abnormally when ODS Graphics is enabled and the options PLOTS=MEANPLOT, LINES, and AJDUST= are specified in the LSMEANS statement.

The following error and traceback could be issued:

   ERROR:  An exception has been encountered.
   Please contact technical support and provide them with the following traceback information:
   
   The SAS task name is [GLIMMIX]
   Exception occurred at (3B5D0F74)
   Task Traceback
   Address   Frame     (DBGHELP API Version 4.0 rev 5)
   3B5D0F74  07F3E6D8  sasglimm:tkvercn1+0x11FF34
   3B4E3654  07F3E724  sasglimm:tkvercn1+0x32614
   3B524EDE  07F3F3A0  sasglimm:tkvercn1+0x73E9E
   3B4B14AB  07F3FF54  sasglimm:tkvercn1+0x46B
   00B92DC4  07F3FFA0  sashost:Main+0xCF84
   00C86038  07F3FFB4  sashost:Main+0x1001F8
   7C80B729  07F3FFEC  kernel32:GetModuleFileNameA+0x1BA

It might be possible to circumvent the problem by omitting the PLOTS=MEANPLOT option. PROC SGPLOT can be used instead to create a plot of the least squares means. To do this, save the ODS table Least Squares Means to a data set by adding the statement

   ods output LSMeans=lsmeans;

and then in a SCATTER statement in PROC SGPLOT, specify X=fixed-effect and Y=ESTIMATE. See the Full Code tab for examples.

Operating System and Release Information

data Yields;
   input Vendor Pressure Temp Yield @@;
   datalines;
 1  1  1  10.20    1  1  2   9.48    1  2  1   9.74
 1  2  2   8.92    1  3  1  11.79    1  3  2   8.85
 2  1  1  10.43    2  1  2  10.59    2  2  1  10.29
 2  2  2  10.15    2  3  1  11.12    2  3  2   9.30
 3  1  1   6.46    3  1  2   7.34    3  2  1   9.44
 3  2  2   8.11    3  3  1   9.38    3  3  2   8.37
 4  1  1   7.36    4  1  2   9.92    4  2  1  10.99
 4  2  2  10.34    4  3  1  10.24    4  3  2   9.96
 5  1  1  11.72    5  1  2  10.60    5  2  1  11.28
 5  2  2   9.03    5  3  1  14.09    5  3  2   8.92
;
ods graphics on;
* MAIN EFFECT;
proc glimmix data=Yields;
ods select MeanPlot;
ods output LSMeans=lsmeans;
   class Vendor Pressure Temp;
   model Yield = Pressure Temp Pressure*Temp;
   random Vendor;
   lsmeans Pressure / plot=meanplot;
run;
title 'LS-Means from Pressure';
proc sgplot data=lsmeans;
  label  Estimate='Yield LS-Mean';
  scatter x=Pressure y=Estimate;
  refline 9 to 11 by 0.5/axis=y lineattrs=(color=CXe6e6e6);
run;
title;

* INTERACTION;
proc glimmix data=Yields;
ods select MeanPlot;
ods output LSMeans=lsmeans;
   class Vendor Pressure Temp;
   model Yield = Pressure Temp Pressure*Temp;
   random Vendor;
   lsmeans Pressure*Temp / plot=meanplot;
run;
proc print ;
run;
data lsmeans;
  set lsmeans;
  interaction=cat(Pressure,' ', Temp);
run;
title 'LS-Means from Pressure*Temp';
proc sgplot data=lsmeans;
  label interaction='Pressure*Temp' estimate='Yield LS-Mean';
  scatter x=interaction y=estimate;
  refline 9 to 11 by 0.5/axis=y lineattrs=(color=CXe6e6e6);
run;
title;